minecraft-snuvi-scripts/system/tiploop.txt

msg("dev", "§bTip-Loop §rloaded.");
prefix_tips = "§eTips";
index = 0;
sgoto(100, "tip_loop");

@wait
wait();
goto("wait");

@tip_loop
//get next tip
list = getLoopTipps();
size = list.getSize(list);
if(size == 0) {
	goto("wait");
}
index++;
if(index >= size) {
	index = 0;
}
a = list.getIndex(list, index);
tipp_value = a[1];
link = false;
if(text.contains(tipp_value, "https://")) {
	link = true;
	a = text.getLinkMessage(tipp_value);
	msg_before = a[0];
	msg_link = a[1];
	msg_after = a[2];
}
//loop online players
online_list = players.toList();
iter = iterator(online_list);
while(hasNext(iter)) {
	p = next(iter);
	if(player.getTipLoop(p)) {
		if(link) {
			msg(p, concat("§r[", prefix_tips, "§r] "), msg_before, msg_link, msg_after);
		} else {
			msg(p, concat("§r[", prefix_tips, "§r] ", tipp_value));
		}
	}
}
sgoto(12000, "tip_loop");
goto("wait");

function getLoopTipps() {
	list = list.new();
	stmt = databank.prepare("SELECT tipp_key, tipp_value FROM tipps WHERE tipp_loop = TRUE");
	result = databank.execute(stmt);
	while(databank.next(result)) {
		a = array.new(2);
		a[0] = databank.getString(result, 1);
		a[1] = databank.getString(result, 2);
		list.add(list, a);
	}
	databank.close(result);
	databank.close(stmt);
	return list;
}