minecraft-snuvi-scripts/system/fixitems.txt

event.load("entity_click");
event.load("inv_click");
event.load("inv_close");

arrow_right = read.item("km:arrow_right", 1, "§fConvert");
air_item = read.item("minecraft:air");

msg("dev", "§bFixItems §rloaded.");
@wait
wait();
if(event == "entity_click") {
	entity_type = entity.getType(entity);
	if(entity_type != "human") {
		goto("wait");
	}
	entity_name = entity.getName(entity);
	if(entity_name != "effects and tags\nRemove item") {
		goto("wait");
	}
	inv = inv.new("001020100");
	inv.setItem(inv, 1, arrow_right);
	inv.open(inv, player, "Remove item effects and tags");
	goto("wait");
}
if(event == "inv_close") {
	player.safeGiveItem(player, inv.getItem(inv, 0));
	player.safeGiveItem(player, inv.getItem(inv, 2));
	waitfor(2);
	inv.update(player);
	goto("wait");
}
if(event == "inv_click") {
	if(inv_slot == 1) {
		//Ziel-slot muss leer sein
		item = inv.getItem(inv, 2);
		if(item.getType(item) != "minecraft:air") {
			goto("wait");
		}
		//Quell-slot muss belegt sein
		item = inv.getItem(inv, 0);
		item_type = item.getType(item);
		if(item_type == "minecraft:air") {
			goto("wait");
		}
		//flawless gemstone ignorieren
		if(item_type == "km:flawless_gem_stone") {
			goto("wait");
		}
		//potion ignorieren
		if(item_type == "minecraft:potion" || item_type == "minecraft:splash_potion" || item_type == "minecraft:lingering_potion") {
			goto("wait");
		}
		//Quell-item kopieren
		item_amount = item.getAmount(item);
		new_item = read.item(item_type, item_amount);
		if(item.isDamageable(new_item)) {
			durability = item.getDamage(item);
			item.setDamage(new_item, durability);
		}
		inv.setItem(inv, 0, air_item) ;
		inv.setItem(inv, 2, new_item);
		inv.update(player);
	}
}
goto("wait");