minecraft-snuvi-scripts/Archiv/insel1/insel1_bauer_wheat.txt

#%waitfor 100;
%speak $player-name §6$kapitän §eUnsere Voräte! Alle weg! Oh wehe dem Bösen mit seiner Magie! Bitte hilf $bauer beim Einholen der Ernte, denn wir benötigen dringend Nahrung. Frage ihn am besten selbst. Du findest Johann, wenn du dem Weg bis zum Ende der Insel folgst.;
%loadEvent entity-click;
%loadEvent entity-hurt;
%setVar no-join true;
%setVar edge1 rpg:-25:66:21;
%setVar edge2 rpg:-21:66:17;
%setVar art CROPS;

%setVar x1 %coords $edge1 x;;
%setVar y1 %coords $edge1 y;;
%setVar z1 %coords $edge1 z;;

%setVar x2 %coords $edge2 x;;
%setVar y2 %coords $edge2 y;;
%setVar z2 %coords $edge2 z;;

%if $x1 < $x2 goto override1;
%setVar helper $x2;
%setVar x2 $x1;
%setVar x1 $helper;
@override1

%if $y1 < $y2 goto  override2;
%setVar helper $y2;
%setVar y2 $y1;
%setVar y1 $helper;
@override2

%if $z1 < $z2 goto  override3;
%setVar helper $z2;
%setVar z2 $z1;
%setVar z1 $helper;
@override3

%setVar helper null;

%setVar x $x1;
@start_x
%setVar y $y1;
@start_y
%setVar z $z1;
@start_z

%setVar loc2 %concat rpg: $x : $y : $z;;
%setVar loc %modLoc $loc2 0 -1 0;;

%setVar type %blockType $loc;;

%if $type == SOIL goto setArt;
%goto override4;

@setArt
%setBlock $loc2 %concat $art :7;;

@override4
%setVar z %add $z 1;;
%if $z <= $z2 goto start_z;

%setVar y %add $y 1;;
%if $y <= $y2 goto start_y;

%setVar x %add $x 1;;
%if $x <= $x2 goto start_x;

@start
%wait;
%if $event == entity-click  || $event == entity-hurt && %distance $entity-loc $bauerloc; < 5 goto farmer;
%goto start;

@farmer
%setVar cancel true;
%speak all §6$bauer §eAhh, $kapitän hat dich geschickt, kannst du bitte 6 Stück reifes Getreide ernten.;
%unloadEvent entity-click;
%loadEvent block-break;
%setVar broken 0;

@break
%wait;
%if $event == block-break && $block-type == CROPS && $block-data == 7 goto farmer2;
%setVar cancel true;
%goto break;

@farmer2
%setVar cancel false;
%setVar broken %add $broken 1;;
%if $broken < 6 goto break;

%speak all §6$bauer §eDanke, das sollte fürs Erste reichen. Komm nun zurück und gib mir das Getreide.;
%setVar given 0;
%loadEvent villager-give;
@last
%wait;
%if $event == villager-give && $item-type == WHEAT && %distance $entity-loc $bauerloc; < 5 goto add;
%setVar cancel true;
%goto last;

@add
%setVar cancel false;
%setVar given %add $given $item-amount;;
%if $given < 6 goto last;

%giveItemPlayer $player-name BREAD:0:2;
%speak all §6$bauer §eHier, damit du nicht ganz leer ausgehst. Danke für deine Hilfe.;
%speak all §6$bauer §eSprich mich für eine weitere Quest erneut an.;
%speak all §6$bauer §eGib "%percent;quest" in den Chat ein, um zu sehen, welche Quests du noch bei wem bekommen kannst.;
%setGlobalVar $player-name insel1_bauer_wheat true;
%endQuest 3;