minecraft-snuvi-scripts/global/jailsystem.txt

event.load("custom_command");
event.load("player_logout");

list.new(jailed);

ironbars = read.item("minecraft:iron_bars", 1, 0, "§r");
jailmenu = inv.new("222222222", "§8Gefängnis");
inv.setItem(jailmenu, 0, ironbars);
inv.setItem(jailmenu, 1, ironbars);
inv.setItem(jailmenu, 2, ironbars);
inv.setItem(jailmenu, 3, ironbars);
inv.setItem(jailmenu, 4, ironbars);
inv.setItem(jailmenu, 5, ironbars);
inv.setItem(jailmenu, 6, ironbars);
inv.setItem(jailmenu, 7, ironbars);
inv.setItem(jailmenu, 8, ironbars);
msg("dev", "§bJailsystem §rwurde geladen");

@wait
wait();
igoto(event);
goto("wait");

@loop
size = list.getSize(jailed);
for(i = 0; i <= size - 1; i++) {
	pname = list.getIndex(jailed, i);
	invopen(pname);
}
if(size > 0) {
	sgoto(10, "loop");
}
goto("wait");

@player_logout
list.remove(jailed, player_name);
goto("wait");

@custom_command
size = list.getSize(args, 0);
if(!perm.has(player, "jail")) {
	goto("wait");
}
if(command == "jail") {
	if(size != 1) {
		msg(player, "§5/jail <name>");
	} else {
		pname = list.getIndex(args, 0);
		if(!isregistered(pname)) {
			player.speak(player, "§5Jail", "§rDieser Spieler war noch nie online");
			goto("wait");
		}
		if(isjailed(pname)) {
			player.speak(player, "§5Jail", "§rDieser Spieler ist bereits gejailt");
			goto("wait");
		}
		if(player_name == pname) {
			player.speak(player, "§5Jail", "§rSich selbst zu jailen ist keine gute Idee");
			goto("wait");
		}
		if(!isonline(pname)) {
			player.speak(player, "§5Jail", "§rDieser Spieler ist nicht online");
			goto("wait");
		}
		p = read.player(pname);
		if(perm.has(p, "jail")) {
			player.speak(player, "§5Jail", "§rDieser Spieler darf nicht gejailt werden");
			goto("wait");
		}
		list.add(jailed, pname);
		player.speak(player, "§5Jail", pname, " wurde gejailt");
		invopen(pname);
		sgoto(1, "loop");
	}
	goto("wait");
}
if(command == "unjail") {
	if(size != 1) {
		msg(player, "§5 /unjail <name> §rJail aufheben");
	} else {
		pname = list.getIndex(args, 0);
		if(!isregistered(pname)) {
			player.speak(player, "§5Jail", "§rDieser Spieler war noch nie online");
			goto("wait");
		}
		if(!isjailed(pname)) {
			player.speak(player, "§5Jail", "§rDieser Spieler ist nicht gejailt");
			goto("wait");
		}
		list.remove(jailed, pname);
		player.speak(player, "§5Jail", "§rDer Spieler wurde aus dem Gefängnis befreit");
		goto("wait");
	}
}
goto("wait");

function invopen(player_name) {
	if(isonline(player_name)) {
		inv.open($jailmenu, read.player(player_name));
	}
	return;
}

function isregistered(player_name) {
	if(player.getUuid(player_name) != null) {
		return true;
	}
	return false;
}

function isjailed(player_name) {
	if(list.contains($jailed, player_name)) {
		return true;
	}
	return false;
}

function isonline(player_name) {
	if(read.player(player_name) == null) {
		return false;
	}
	return true;
}