minecraft-snuvi-scripts/story/spawn/stonemage.txt

event.load("human_hurt");
event.load("entity_click");
event.load("block_click");
event.load("custom_command");
event.load("quest_start");
event.load("quest_term");
event.load("living_death");
event.load("bucket_use");
event.load("block_break");

quest_no = 0;
rnd_list = list.new();
list.add(rnd_list, 1);
list.add(rnd_list, 2);
list.add(rnd_list, 3);
list.add(rnd_list, 4);
list.shuffle(rnd_list);

furnace_clicked = false;
bucket_filled = false;
cauldron_filled = false;
cave_spider_killed = false;
warts_harvested = 0;
mob_killed = 1;
stage = 0;
all_stages = 34;
quest_name = "Stone Mage";

open_prop = block.getproperty("open");
half_prop = block.getproperty("double_block_half");
key = read.item("km:golden_key", 1, "Tower Key", "Stone Mage");

world = world.get("overworld");
zombie_loc = loc.new(world, 288.5, 81, 401.5);
skeleton_loc = loc.new(world, 282.5, 83, 400.5);
blaze_loc = loc.new(world, 280.5, 86, 395.5);
spider_loc = loc.new(world, 289, 91, 398);
witch_loc = loc.new(world, 285.5, 95, 398.5);
cauldron_loc = loc.new(world, 285, 108, 404);
cave_spider_loc = loc.new(world, 284.5, 116, 397.5);

doors_to_close = list.new();
visited_doors = list.new();
iron_doors = list.new();
list.add(iron_doors, loc.new(world, 283, 78, 394));
list.add(iron_doors, loc.new(world, 284, 80, 401));
list.add(iron_doors, loc.new(world, 288, 81, 397));
list.add(iron_doors, loc.new(world, 280, 82, 395));
list.add(iron_doors, loc.new(world, 288, 86, 396));
list.add(iron_doors, loc.new(world, 284, 91, 400));
list.add(iron_doors, loc.new(world, 282, 95, 395));
list.add(iron_doors, loc.new(world, 282, 97, 398));

@wait
wait();
if(event == "human_hurt") {
	player = entity;
}
if(event == "quest_term") {
	player = player.get(quest_player_uuid);
}
if(event == "living_death") {
	player = player.getFromDamageSource(damage_source);
	if(player == null) {
		goto("wait");
	}
}
if(quest_player_uuid == player.getUuid(player)) {
	ignoreGoto(event);
}
goto("wait");

@quest_start
msg.quest(player, "Mentos", 1, 3, "How am I still alive? It must have been a dream.");
stage.increase(player);
goto("wait");

@quest_term
player.removeItem(player, key);
goto("wait");

@human_hurt
entity = human;
goto("human_core");

@entity_click
if(hand == "OFF_HAND") {
	goto("wait");
}
if(entity.getType(entity) != "human") {
	goto("wait");
}
goto("human_core");

@human_core
entity_name = entity.getName(entity);
if(entity_name == "Mentos") {
	if(stage == 1) {
		msg.quest(player, entity_name, 2, 3, "Monsters and a mage are part of it. A mage in a tower.");
		stage.increase(player);
	} elseif(stage == 2) {
		msg.quest(player, entity_name, 3, 3, "Look behind you. There's a door.");
		stage.increase(player);
	}
	goto("wait");
}
if(entity_name == "Mage's apprentice") {
	if(stage == 3) {
		msg.quest(player, entity_name, 1, 4, "The key to the mage? You can have it if you give me bread.");
		stage.increase(player);
	} elseif(stage == 4) {
		hand_item = entity.getEquip(player, "hand");
		if(item.getType(hand_item) == "minecraft:bread") {
			msg.quest(player, entity_name, 2, 4, "Right click doors to open them.");
			safeGiveItemPlayer(player, key);
			player.removeItem(player, read.item("minecraft:bread"));
			stage.increase(player);
		}
	} elseif(stage == 5) {
		msg.quest(player, entity_name, 3, 4, "On your way to the mage, you have to cross several rooms.");
		stage.increase(player);
	} elseif(stage == 6) {
		msg.quest(player, entity_name, 4, 4, "Be aware.");
		stage.increase(player);
	}
}
if(entity_name == "Stone Mage") {
	if(stage == 20) {
		msg.quest(player, entity_name, 1, 10, "Please give me the Tower Key.");
		stage.increase(player);
	} elseif(stage == 21) {
		hand_item = entity.getEquip(player, "hand");
		if(item.getType(hand_item) == "km:golden_key" && item.getName(hand_item) == "Tower Key") {
			msg.quest(player, entity_name, 2, 10, "Before offering you skills you have to finish some tasks for me.");
			player.removeItem(player, key);
			stage.increase(player);
			talk_no = 3;
			active_quest = false;
		}
	} elseif(stage >= 22 && stage < 33) {
		if(active_quest) {
			hand_item = entity.getEquip(player, "hand");
			if(i == 3 && item.getType(hand_item) == "minecraft:nether_wart" && warts_harvested >= 4) {
				msg.quest(player, entity_name, talk_no++, 10, "Thank you.");
				player.removeItem(player, read.item("minecraft:nether_wart", warts_harvested));
				stage.increase(player);
				active_quest = false;
			}
			if(i == 4 && item.getType(hand_item) == "km:mushroom_stick_cooked" && furnace_clicked) {
				msg.quest(player, entity_name, talk_no++, 10, "Thank you.");
				player.removeItem(player, read.item("km:mushroom_stick_cooked"));
				stage.increase(player);
				active_quest = false;
			}
			goto("wait");
		}
		active_quest = true;
		i = list.getIndex(rnd_list, quest_no++);
		if(i == 1) {
			msg.quest(player, entity_name, talk_no++, 10, "A spider has nested in my attic. Please go up and kill it.");
			entity.spawn("cave_spider", cave_spider_loc);
			stage.increase(player);
		} elseif(i == 2) {
			msg.quest(player, entity_name, talk_no++, 10, "Take this bucket, fill it with water and then pour it into the cauldron.");
			safeGiveItemPlayer(player, read.item("minecraft:bucket"));
			block.set(cauldron_loc, "minecraft:cauldron[level=0]");
			stage.increase(player);
		} elseif(i == 3) {
			msg.quest(player, entity_name, talk_no++, 10, "Go upstairs, pick some nether warts there and then give me all you have harvested!");
			stage.increase(player);
		} elseif(i == 4) {
			msg.quest(player, entity_name, talk_no++, 10, "Please go downstairs and cook this for me.");
			safeGiveItemPlayer(player, read.item("minecraft:coal"));
			safeGiveItemPlayer(player, read.item("km:mushroom_stick_raw"));
			stage.increase(player);
		}
	} elseif(stage == 33) {
		spawn_script = script.get("SpawnQuests");
		map = script.getVar(spawn_script, "timestamp");
		map.add(map, player.getUuid(player), time.getMillis());
		msg(player, "§dQuest completed. Reward: 50 Coins!");
		addMoney(player, 20);
		quest.finish(script, player);
	}
}
//Mushroomstick braten
goto("wait");

@block_click
if(hand == "OFF_HAND") {
	goto("wait");
}
hand_item = entity.getEquip(player, "hand");
if(stage >= 22) {
	if(i == 2 && bucket_filled && !cauldron_filled && block.getType(block_loc) == "minecraft:cauldron" && item.getType(hand_item) == "minecraft:water_bucket") {
		msg.quest(player, entity_name, talk_no++, 10, "Well done. Come back to me.");
		active_quest = false;
		cauldron_filled = true;
		stage.increase(player);
		player.removeItem(player, read.item("minecraft:water_bucket"));
		block.set(cauldron_loc, "minecraft:cauldron[level=3]");
		goto("wait");
	}
	if(i == 4 && !furnace_clicked && block.getType(block_loc) == "minecraft:furnace") {
		furnace_clicked = true;
		stage.increase(player);
		goto("wait");
	}
}
if(!(item.getType(hand_item) == "km:golden_key" && item.getName(hand_item) == "Tower Key")) {
	goto("wait");
}
if(block.getType(block_loc) == "minecraft:iron_door") {
	state_open = block.getState(block_loc, open_prop);
	state_half = block.getState(block_loc, half_prop);
	if(state_half == "upper") {
		door_loc = loc.mod(block_loc, 0, -1, 0);
	} else {
		door_loc = block_loc;
	}
	if(list.contains(visited_doors, door_loc)) {
		if(!state_open) {
			opendoor(door_loc);
			sgoto(60, "closedoor");
		}
		goto("wait");
	}
	if(list.contains(iron_doors, door_loc)) {
		if(stage == 7) {
			stage.increase(player);
		} elseif(stage == 8) {
			stage.increase(player);
			entity.spawn("zombie", zombie_loc);
		} elseif(stage == 10 && mob_killed == 1) {
			stage.increase(player);
		} elseif(stage == 11) {
			stage.increase(player);
			entity.spawn("skeleton", skeleton_loc);
		} elseif(stage == 13 && mob_killed == 1) {
			stage.increase(player);
			entity.spawn("blaze", blaze_loc);
		} elseif(stage == 15 && mob_killed == 1) {
			stage.increase(player);
			entity.spawn("spider", spider_loc);
		} elseif(stage == 17 && mob_killed == 1) {
			stage.increase(player);
			entity.spawn("witch", witch_loc);
		} elseif(stage == 19 && mob_killed == 1) {
			stage.increase(player);
		} else {
			goto("wait");
		}
		if(!state_open) {
			mob_killed = 0;
			opendoor(door_loc);
			sgoto(60, "closedoor");
		}
	}
}
goto("wait");

function opendoor(loc) {
	block.setDoorStatus(loc, true);
	list.add($doors_to_close, loc);
	if(!list.contains($visited_doors, loc)) {
		list.add($visited_doors, loc);
	}
}

@closedoor
doorloc = list.getIndex(doors_to_close, 0);
list.removeIndex(doors_to_close, 0);
if(block.getType(doorloc) == "minecraft:iron_door") {
	if(block.getDoorStatus(doorloc)) {
		block.setDoorStatus(doorloc, false);
	}
}
goto("wait");

@bucket_use
if(stage >= 22 && i == 2 && !bucket_filled) {
	cancel = false;
	stage.increase(player);
	bucket_filled = true;
}
goto("wait");

@block_break
if(stage >= 22 && i == 3) {
	cancel = true;
	if(block.getType(block_loc) == "minecraft:nether_wart" && warts_harvested < 4) {
		cancel = true;
		amount = math.random(1, 3);
		item.drop(block_loc, read.item("minecraft:nether_wart", amount));
		warts_harvested += amount;
		if(warts_harvested >= 4) {
			stage.increase(player);
		}
	}
}
goto("wait");

@living_death
entity_type = entity.getType(living_entity);
if(stage == 9 && entity_type == "zombie") {
	mob_killed = 1;
	stage.increase(player);
}
if(stage == 12 && entity_type == "skeleton") {
	mob_killed = 1;
	stage.increase(player);
}
if(stage == 14 && entity_type == "blaze") {
	mob_killed = 1;
	stage.increase(player);
}
if(stage == 16 && entity_type == "spider") {
	mob_killed = 1;
	stage.increase(player);
}
if(stage == 18 && entity_type == "witch") {
	mob_killed = 1;
	stage.increase(player);
}
if(stage >= 22 && i == 1 && entity_type == "cave_spider" && !cave_spider_killed) {
	msg.quest(player, entity_name, talk_no++, 10, "Great job. Come back to me.");
	stage.increase(player);
	cave_spider_killed = true;
	active_quest = false;
}
goto("wait");