minecraft-snuvi-scripts/Archiv/story/schiff/schiff_8_Ich_bin_durstig.txt

%if %getGlobalVar $player-name schiff7; == true goto start;
%q term;

@start
%msg all Nimm diese 3 Glas und crafte daraus 3 Glasflaschen. Bitte befülle sie mit Wasser und bringe sie mir.;
%loadEvent craft;
%giveItemPlayer $player-name GLASS:0:3;

@wait1
%wait;
%if $event == craft && $item-type == GLASS_BOTTLE goto craft;
%goto wait1;

@craft
%setVar filled 0;
%unloadEvent craft;
%loadEvent block-click;

@wait2
%wait;
%if $event == block-click && $player-item == GLASS_BOTTLE && $action == RIGHT_CLICK_BLOCK goto fill;
%goto wait2;

@fill
%setVar filled %add $filled 1;
%if $filled >= 3 goto startgive;
%goto wait2;

@startgive
%unloadEvent block-click;
%loadEvent villager-give;
%setVar given 0;

@wait3
%wait;
%if $event == villager-give && $item-type == POTION goto checkloc;
%setVar cancel true;
%msg all Was soll ich damit?;
%goto wait3;

@checkloc
%if %distance $villager-loc $shipstartloc; <= 4 goto give;
%setVar cancel true;
%msg all Tut mir leid, ich bin nicht dein Kamerad.;
%goto wait3;

@give
%setVar given %add $given $item-amount;;
%if $given >= 3 goto endQuest;
%msg all Ich brauche noch %sub 3 $given; Wasserflaschen.;
%goto wait3;

@endQuest
%setGlobalVar $player-name schiff8 true
%setGlobalVar $player-name schiff7 false;
%msg all Vielen Dank, mir geht es schon viel besser.;
%endQuest 4;