%msg all §bLobby_1vs1 wurde geladen.;
%loadEvent chat;
%loadEvent block-place;
%loadEvent block-break;
%loadEvent player-hurt;
%setVar lobbyloc games:-1002:101:-6004;
%setVar lobbyradius 30;

@wait
%wait;
%if $world-name != games goto wait;
%if $event == chat goto checkarg0;
%if $event == player-hurt && $world-name == games goto checkblockdistance;
%if $event == block-break || $event == block-place && %distance $block-loc $lobbyloc; < $lobbyradius goto cancel;
%goto wait;

@checkblockdistance
%if %distance $player-loc $lobbyloc; < 30 goto cancel;
%goto wait;

@cancel
%setVar cancel true;
%goto wait;

@checkarg0
%if %getListElementAt args 0; == invite goto checkinvitearg1;
%if %getListElementAt args 0; == accept goto checkacceptarg1;
%goto wait;

@checkinvitearg1
%if %isValid %getListElementAt args 1;; == false goto jump2;
%if %distance $player-loc $lobbyloc; < $lobbyradius && %distance %getPlayerLoc %getListElementAt args 1;; $lobbyloc; < $lobbyradius goto invite;
@jump2
%speak $player-name %concat §d 1vs1; §eDieser Spieler ist nicht in der Lobby oder am Server.;
%goto wait;

@invite
%if %getListElementAt args 1; != $player-name goto jump1;
%speak $player-name %concat §d 1vs1; §eDu kannst dich nicht selbst einladen.;
%goto wait;
@jump1
%setGlobalVar $player-name invite %getListElementAt args 1;;
%speak $player-name %concat §d 1vs1; §eDu hast %getListElementAt args 1; herausgefordert.;
%speak %getListElementAt args 1; %concat §d 1vs1; %concat §e $player-name; hat dir eine Anfrage geschickt. Gib "%percent;accept [Spieler]" in den Chat ein, um die Anfrage anzunehmen.;
%goto wait;

@checkacceptarg1
%if %isValid %getListElementAt args 1;; == false goto jump3;
%if %distance $player-loc $lobbyloc; < $lobbyradius && %distance %getPlayerLoc %getListElementAt args 1;; $lobbyloc; < $lobbyradius && %getGlobalVar %getListElementAt args 1; invite; == $player-name goto fight;
@jump3
%speak $player-name %concat §d 1vs1; §eDieser Spieler ist nicht mehr in der Lobby oder am Server.;
%goto wait;

@fight
%speak $player-name %concat §d 1vs1; §eDu hast die Anfrage von %getListElementAt args 1; angenommen.;
%speak %getListElementAt args 1; %concat §d 1vs1; %concat §e $player-name; hat deine Anfrage angenommen.;
%givequest $player-name minigames/region_1vs1map1;
%givequest %getListElementAt args 1; minigames/region_1vs1map1;
%goto wait;