event.load("custom_command");
event.load("item_air_click");
event.load("left_click_air");
command.add("hunt");
command.add("compass");

prefix = "§hHunt";
hunters = list.new();
compass_type = "minecraft:compass";
compass = read.item(compass_type);

msg("dev", "§bHunter §rwurde geladen");
@wait
wait();
//Wenn Event aus Hunter-Welt, dann wird er verarbeitet
if(player == null) {
	goto("wait");
}
player_loc = entity.getLocation(player);
world_name = world.getName(loc.getWorld(player_loc));
if(isSurvWorldName(world_name)) {
	ignoreGoto(event);
}
goto("wait");

@custom_command
size = list.getSize(args);
if(command == "hunt") {
	if(!perm.has(player, "isSnuviMaster")) {
		speakPrefix(player, prefix, "Keine Permissions");
		goto("wait");
	}
	if(size < 2) {
		speakPrefix(player, prefix, "/hunt <hunter> <runner>");
		goto("wait");
	}
	hunter_name = list.getIndex(args, 0);
	if(!checkIfEverOnline(hunter_name)) {
		speakPrefix(player, prefix, "§rDer angegebene Hunter war noch nie online");
		goto("wait");
	}
	if(!isOnline(hunter_name)) {
		speakPrefix(player, prefix, "§rDer angegebene Hunter ist nicht online");
		goto("wait");
	}
	runner_name = list.getIndex(args, 1);
	if(!checkIfEverOnline(runner_name)) {
		speakPrefix(player, prefix, "§rDer angegebene Runner war noch nie online");
		goto("wait");
	}
	if(!isOnline(runner_name)) {
		speakPrefix(player, prefix, "§rDer angegebene Runner ist nicht online");
		goto("wait");
	}
	hunter = read.player(hunter_name);
	if(player.getItemAmount(hunter, false, compass) == 0) {
		player.giveItem(hunter, compass);
	}
	list.add(hunters, player.getUuid(hunter_name));
	runner_uuid = player.getUuid(runner_name);
	goto("wait");
}
if(command == "compass") {
	uuid = player.getUuid(player);
	if(list.contains(hunters, uuid)) {
		if(player.getItemAmount(player, false, compass) == 0) {
			player.giveItem(player, compass);
		}
	}
	goto("wait");
}
goto("wait");

@left_click_air
@item_air_click
if(item.getType(entity.getEquip(player, "hand")) == compass_type || item.getType(entity.getEquip(player, "offhand")) == compass_type) {
	uuid = player.getUuid(player);
	if(list.contains(hunters, uuid)) {
		if(isOnline(player.getName(runner_uuid))) {
			player.setCompass(player, entity.getLocation(player.get(runner_uuid)));
			speakPrefix(player, prefix, "Kompass neu gesetzt.");
		} else {
			speakPrefix(player, prefix, "Runner nicht online.");
		}
	} else {
		speakPrefix(player, prefix, "Du bist kein Hunter.");
	}
}
goto("wait");