msg("dev", "§bbuildcontest §rwurde geladen");
event.load("block_click");
event.load("block_break");
event.load("block_place");

list.new("joinlocs");
list.add(joinlocs, read.location("games:4:75:70"));
list.add(joinlocs, read.location("games:4:75:68"));

@wait
wait();
if(event == "block_click") {
	if(list.contains(joinlocs, block_loc)) {
		if(ggv(player_name, "buildplotloc") == null || ggv(player_name, "buildplotloc") == "wusi") {
			counter = 0;
			sbz = -14999;
			@sbzgsfinder
			sbx = -14999;
			@sbxgsfinder
			gs1 = read.location(concat("vespilan:", sbx, ":0:", sbz));
			gs2 = read.location(concat("vespilan:", sbx + 31, ":255:", sbz + 31));
			if(plot.doesIntersect(gs1, gs2) == false) {
				temploc = loc.mod(gs1, 15.5, 37, -0.5);
				loc.setYaw(temploc, 0);
				loc.setPitch(temploc, 0);
				sgv(player_name, "buildplotloc", text.location(temploc));
				plot.add(gs1, gs2, player_name);
				block.set(loc.mod(gs1, 0, 37, 0), read.item("STONE_SLAB"));
				block.set(loc.mod(gs1, 31, 37, 0), read.item("STONE_SLAB"));
				block.set(loc.mod(gs1, 0, 37, 31), read.item("STONE_SLAB"));
				block.set(loc.mod(gs2, 0, -218, 0), read.item("STONE_SLAB"));
				reset();
				entity.teleport(player, temploc);
				if(invert(player.isCreative(player))) {
					command("gamemode creative ", player_name);
				}
				removeVar("temploc");
				goto("wait");
			}
			if(equal(inc("counter"), 300)) {
				waitfor(1);
			}

			sbx += 36;
			if(sbx <= 15501) {
				goto("sbxgsfinder");
			}
			sbz += 36;	
			if(sbz <= 15501) {
				goto("sbzgsfinder");
			}
			player.speak(player, "§4Fehler", "§rDie ganze Welt ist mit Grundstücken besetzt. Bitte teile dies einem Moderator mit.");
			goto("wait");
		} else {
			entity.teleport(player, read.location(ggv(player_name, "buildplotloc")));
			if(invert(player.isCreative(player))) {
				command("gamemode creative ", player_name);
			}
		}
	}
}
if(event == "block_break" || event == "block_place") {
	if(loc.getCoord(block_loc, "w") == "vespilan") {
		if(plot.doesIntersect(block_loc, block_loc) == false) {
			cancel = true;
		}
	}
	goto("wait");
}
goto("wait");