ccore/CMakeLists.txt

cmake_minimum_required(VERSION 3.25)
project(core)

set(CMAKE_C_STANDARD 23)

set(SRC
    "src/BitArray.c"
    "src/Box.c"
    "src/Buffer.c"
    "src/Frustum.c"
    "src/LinkedList.c"
    "src/List.c"
    "src/Logger.c"
    "src/Matrix.c"
    "src/Plane.c"
    "src/Quaternion.c"
    "src/Random.c"
    "src/SpinLock.c"
    "src/Utility.c"
    "src/Vector.c"
    "src/View.c"
)

set(SRC_TESTS
    "test/Main.c"
    "test/Test.c"
    "test/modules/BitArrayTests.c"
    "test/modules/BoxTests.c"
    "test/modules/BufferTests.c"
    "test/modules/FrustumTests.c"
    "test/modules/LinkedListTests.c"
    "test/modules/ListTests.c"
    "test/modules/MatrixTests.c"
    "test/modules/PlaneTests.c"
    "test/modules/QuaternionTests.c"
    "test/modules/RandomTests.c"
    "test/modules/SpinLockTests.c"
    "test/modules/UtilityTests.c"
    "test/modules/VectorTests.c"
    "test/modules/ViewTests.c"
    #"test/modules/ComponentsTests.cpp"
    #"test/modules/HashMapTests.cpp"
    #"test/modules/RingBufferTests.cpp"
)

set(SRC_PERFORMANCE
    #"performance/Main.cpp"
    #"test/Test.cpp"
)

if("${CMAKE_BUILD_TYPE}" STREQUAL "Release")
    set(COMPILE_OPTIONS -flto)
    set(LINK_OPTIONS -flto)
    set(LOG_LEVEL 2)
    set(DEFINITIONS "")
else()
    set(DEFINITIONS ERROR_SIMULATOR CORE_CHECK_MEMORY)
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
        set(COMPILE_OPTIONS --coverage)
        set(LINK_OPTIONS gcov)
    elseif(CMAKE_C_COMPILER_ID STREQUAL "Clang")
        set(COMPILE_OPTIONS -fprofile-instr-generate -fcoverage-mapping)
        set(LINK_OPTIONS ${COMPILE_OPTIONS})
    endif()
    set(LOG_LEVEL 4)
    list(APPEND SRC "src/ErrorSimulator.c")
endif()

if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
    include("cmake/gcc_warnings.cmake")
    set(DEFINITIONS ${DEFINITIONS}
        bool=_Bool
        true=1
        false=0
        nullptr=0
        static_assert=_Static_assert
    )
elseif(CMAKE_C_COMPILER_ID STREQUAL "Clang")
    include("cmake/clang_warnings.cmake")
endif()

add_library(core STATIC ${SRC})
target_compile_options(core PUBLIC
    ${COMPILE_OPTIONS}
    ${WARNINGS}
    -fdiagnostics-color=always
)
target_compile_definitions(core 
    PUBLIC CORE_LOG_LEVEL=${LOG_LEVEL}
    PRIVATE ${DEFINITIONS}
)
target_link_libraries(core 
    PRIVATE m ${LINK_OPTIONS}
)
target_sources(core PUBLIC 
    FILE_SET HEADERS
    BASE_DIRS include
    FILES 
        ./include/core/BitArray.h
        ./include/core/Box.h
        ./include/core/Buffer.h
        ./include/core/Check.h
        ./include/core/Frustum.h
        ./include/core/LinkedList.h
        ./include/core/List.h
        ./include/core/Logger.h
        ./include/core/Matrix.h
        ./include/core/Plane.h
        ./include/core/Quaternion.h
        ./include/core/Random.h
        ./include/core/SpinLock.h
        ./include/core/Types.h
        ./include/core/Utility.h
        ./include/core/Vector.h
        ./include/core/View.h
#        ./include/core/Components.hpp
#        ./include/core/HashMap.hpp
#        ./include/core/ProbingHashMap.hpp
#        ./include/core/RingBuffer.hpp
)
install(TARGETS core FILE_SET HEADERS)

add_executable(test ${SRC_TESTS})
target_link_libraries(test PRIVATE core)
target_compile_definitions(test PRIVATE ${DEFINITIONS})

#add_executable(performance ${SRC_PERFORMANCE})
#target_link_libraries(performance PRIVATE core)